Fixed qs-hyprview to work with trixie+

Signed-off-by: Don Williams <don.e.williams@gmail.com>

 On branch development
 Your branch is up to date with 'origin/development'.

 Changes to be committed:
	renamed:    qs-hyprview-trixie/LICENSE -> qs-hyprview-unified/LICENSE
	renamed:    qs-hyprview-trixie/README.md -> qs-hyprview-unified/README.md
	renamed:    qs-hyprview-trixie/common/Appearance.qml -> qs-hyprview-unified/common/Appearance.qml
	renamed:    qs-hyprview-trixie/layouts/BandsLayout.qml -> qs-hyprview-unified/layouts/BandsLayout.qml
	renamed:    qs-hyprview-trixie/layouts/ColumnarLayout.qml -> qs-hyprview-unified/layouts/ColumnarLayout.qml
	renamed:    qs-hyprview-trixie/layouts/HeroLayout.qml -> qs-hyprview-unified/layouts/HeroLayout.qml
	renamed:    qs-hyprview-trixie/layouts/JustifiedLayout.qml -> qs-hyprview-unified/layouts/JustifiedLayout.qml
	renamed:    qs-hyprview-trixie/layouts/LayoutsManager.qml -> qs-hyprview-unified/layouts/LayoutsManager.qml
	renamed:    qs-hyprview-trixie/layouts/MasonryLayout.qml -> qs-hyprview-unified/layouts/MasonryLayout.qml
	renamed:    qs-hyprview-trixie/layouts/SatelliteLayout.qml -> qs-hyprview-unified/layouts/SatelliteLayout.qml
	renamed:    qs-hyprview-trixie/layouts/SmartGridLayout.qml -> qs-hyprview-unified/layouts/SmartGridLayout.qml
	renamed:    qs-hyprview-trixie/layouts/SpiralLayout.qml -> qs-hyprview-unified/layouts/SpiralLayout.qml
	renamed:    qs-hyprview-trixie/layouts/StarggeredLayout.qml -> qs-hyprview-unified/layouts/StarggeredLayout.qml
	renamed:    qs-hyprview-trixie/layouts/VortexLayout.qml -> qs-hyprview-unified/layouts/VortexLayout.qml
	renamed:    qs-hyprview-trixie/layouts/qmldir -> qs-hyprview-unified/layouts/qmldir
	renamed:    qs-hyprview-trixie/modules/Hyprview.qml -> qs-hyprview-unified/modules/Hyprview.qml
	renamed:    qs-hyprview-trixie/modules/SearchBox.qml -> qs-hyprview-unified/modules/SearchBox.qml
	renamed:    qs-hyprview-trixie/modules/WindowThumbnail.qml -> qs-hyprview-unified/modules/WindowThumbnail.qml
	renamed:    qs-hyprview-trixie/modules/qmldir -> qs-hyprview-unified/modules/qmldir
	renamed:    qs-hyprview-trixie/qs-hyprview-template.qml -> qs-hyprview-unified/qs-hyprview-template.qml
	renamed:    qs-hyprview-trixie/screenshots/bands.jpeg -> qs-hyprview-unified/screenshots/bands.jpeg
	renamed:    qs-hyprview-trixie/screenshots/hero.jpeg -> qs-hyprview-unified/screenshots/hero.jpeg
	renamed:    qs-hyprview-trixie/screenshots/masonry.jpeg -> qs-hyprview-unified/screenshots/masonry.jpeg
	renamed:    qs-hyprview-trixie/screenshots/satellite.jpeg -> qs-hyprview-unified/screenshots/satellite.jpeg
	renamed:    qs-hyprview-trixie/screenshots/smartgrid.jpeg -> qs-hyprview-unified/screenshots/smartgrid.jpeg
	renamed:    qs-hyprview-trixie/screenshots/spiral.jpeg -> qs-hyprview-unified/screenshots/spiral.jpeg
	renamed:    qs-hyprview-trixie/screenshots/staggered.jpeg -> qs-hyprview-unified/screenshots/staggered.jpeg
	renamed:    qs-hyprview-trixie/screenshots/vortex.jpeg -> qs-hyprview-unified/screenshots/vortex.jpeg
	renamed:    qs-hyprview-trixie/shell.qml -> qs-hyprview-unified/shell.qml

1 files changed, 149 insertions, 0 deletions

diff --git a/config/quickshell/qs-hyprview-unified/layouts/JustifiedLayout.qml b/config/quickshell/qs-hyprview-unified/layouts/JustifiedLayout.qml
new file mode 100644
index 00000000..655147b5
--- /dev/null
+++ b/config/quickshell/qs-hyprview-unified/layouts/JustifiedLayout.qml
@@ -0,0 +1,149 @@
+pragma Singleton
+import Quickshell
+
+Singleton {
+    id: root
+
+    function doLayout(windowList, outerWidth, outerHeight) {
+        var N = windowList.length
+        if (N === 0)
+            return []
+
+        var containerWidth  = outerWidth  * 0.9
+        var containerHeight = outerHeight * 0.9
+
+        // Gap: 0.8% of screen, clamped between 12px and 32px
+        var rawGap = Math.min(outerWidth * 0.08, outerHeight * 0.08)
+        var gap = Math.max(12, Math.min(32, rawGap))
+
+        var maxThumbHeight = outerHeight * 0.3
+
+        if (containerWidth <= 0 || containerHeight <= 0) {
+            return windowList.map(function(item) {
+                return {
+                    win: item.win,
+                    x: 0,
+                    y: 0,
+                    width: 0,
+                    height: 0
+                }
+            })
+        }
+
+        var targetRowH = maxThumbHeight
+        var rows = []
+        var currentRow = []
+        var sumAspect = 0
+
+        function flushRow() {
+            if (currentRow.length === 0)
+                return
+
+            var n = currentRow.length
+            var rowHeight = maxThumbHeight
+            if (sumAspect > 0) {
+                var totalGapWidth = gap * (n - 1)
+                var hFit = (containerWidth - totalGapWidth) / sumAspect
+                if (hFit < rowHeight)
+                    rowHeight = hFit
+            }
+
+            if (rowHeight > maxThumbHeight)
+                rowHeight = maxThumbHeight
+            if (rowHeight <= 0)
+                rowHeight = 1
+
+            rows.push({
+                items: currentRow.slice(),
+                height: rowHeight,
+                sumAspect: sumAspect
+            })
+
+            currentRow = []
+            sumAspect = 0
+        }
+
+        for (var i = 0; i < N; ++i) {
+            var item = windowList[i]
+            var w0 = item.width > 0 ? item.width : 1
+            var h0 = item.height > 0 ? item.height : 1
+            var a = w0 / h0
+            item.aspect = a
+
+            if (currentRow.length > 0 &&
+                ((sumAspect + a) * targetRowH + gap * currentRow.length) > containerWidth) {
+                flushRow()
+            }
+
+            currentRow.push(item)
+            sumAspect += a
+        }
+
+        if (currentRow.length > 0) {
+            flushRow()
+        }
+
+        var totalRawHeight = 0
+        for (var r = 0; r < rows.length; ++r) {
+            totalRawHeight += rows[r].height
+        }
+        if (rows.length > 1) {
+            totalRawHeight += gap * (rows.length - 1)
+        }
+
+        var sV = 1.0
+        var availH = containerHeight
+        if (totalRawHeight > 0 && totalRawHeight > availH) {
+            sV = availH / totalRawHeight
+        }
+        if (sV <= 0)
+            sV = 0.1
+        if (sV > 1.0)
+            sV = 1.0
+
+        var gridTotalHeightScaled = totalRawHeight * sV
+        var yAcc = (outerHeight - gridTotalHeightScaled) / 2
+        if (!isFinite(yAcc) || yAcc < 0)
+            yAcc = 0
+
+        var result = []
+
+        for (var r2 = 0; r2 < rows.length; ++r2) {
+            var row = rows[r2]
+            var rowHeightScaled = row.height * sV
+
+            var rowWidthNoGapsScaled = 0
+            for (var j = 0; j < row.items.length; ++j) {
+                rowWidthNoGapsScaled += row.items[j].aspect * rowHeightScaled
+            }
+            var totalRowWidthScaled = rowWidthNoGapsScaled + gap * (row.items.length - 1)
+
+            var xAcc = (outerWidth - totalRowWidthScaled) / 2
+            if (!isFinite(xAcc))
+                xAcc = 0
+
+            for (var j2 = 0; j2 < row.items.length; ++j2) {
+                var it2 = row.items[j2]
+                var wScaled = it2.aspect * rowHeightScaled
+                var hScaled = rowHeightScaled
+
+                result.push({
+                    win: it2.win,
+                    x: xAcc,
+                    y: yAcc,
+                    width: wScaled,
+                    height: hScaled
+                })
+
+                xAcc += wScaled + gap
+            }
+
+            yAcc += rowHeightScaled
+            if (r2 < rows.length - 1) {
+                yAcc += gap * sV
+            }
+        }
+
+        return result
+    }
+}