From f267adf53fbfa8f53bb3e85c5af5e8b925ae8cdc Mon Sep 17 00:00:00 2001
From: RblSb <msrblsb@gmail.com>
Date: Sun, 16 Feb 2025 15:08:15 +0300
Subject: PeerTube support

closes #46
---
 src/client/Main.hx             |   4 +-
 src/client/Player.hx           |   6 +-
 src/client/players/Peertube.hx | 136 +++++++++++++++++++++++++++++++++++++++++
 3 files changed, 142 insertions(+), 4 deletions(-)
 create mode 100644 src/client/players/Peertube.hx

(limited to 'src')

diff --git a/src/client/Main.hx b/src/client/Main.hx
index 660693b..42030dd 100644
--- a/src/client/Main.hx
+++ b/src/client/Main.hx
@@ -330,7 +330,9 @@ class Main {
 			final colonPort = port.length > 0 ? ':$port' : port;
 			url = '$protocol//$host$colonPort$url';
 		}
-		if (!url.startsWith("http")) url = '$protocol//$url';
+		if (!url.startsWith("pt:")) {
+			if (!url.startsWith("http")) url = '$protocol//$url';
+		}
 
 		final obj:VideoDataRequest = {
 			url: url,
diff --git a/src/client/Player.hx b/src/client/Player.hx
index 6be8a07..9b22748 100644
--- a/src/client/Player.hx
+++ b/src/client/Player.hx
@@ -6,6 +6,7 @@ import Types.VideoDataRequest;
 import Types.VideoItem;
 import client.Main.getEl;
 import client.players.Iframe;
+import client.players.Peertube;
 import client.players.Raw;
 import client.players.Streamable;
 import client.players.Vk;
@@ -30,7 +31,6 @@ class Player {
 	var isLoaded = false;
 	var skipSetTime = false;
 	var skipSetRate = false;
-	var streamable:Streamable;
 
 	final voiceOverInput:InputElement = getEl("#voiceoverurl");
 	var audioTrack:Null<Audio>;
@@ -44,11 +44,11 @@ class Player {
 	public function new(main:Main):Void {
 		this.main = main;
 		youtube = new Youtube(main, this);
-		streamable = new Streamable(main, this);
 		players = [
 			youtube,
 			new Vk(main, this),
-			streamable,
+			new Streamable(main, this),
+			new Peertube(main, this),
 		];
 		iframePlayer = new Iframe(main, this);
 		rawPlayer = new Raw(main, this);
diff --git a/src/client/players/Peertube.hx b/src/client/players/Peertube.hx
new file mode 100644
index 0000000..e869980
--- /dev/null
+++ b/src/client/players/Peertube.hx
@@ -0,0 +1,136 @@
+package client.players;
+
+import Types.VideoData;
+import Types.VideoDataRequest;
+import haxe.Http;
+import haxe.Json;
+import js.html.URL;
+
+class Peertube extends Raw {
+	final matchPeertube = ~/^pt:.+\/w\/(p\/)?([A-z0-9]+)/g;
+	final matchOldPeertube = ~/^pt:.+\/videos\/watch\/([-A-z0-9]+)/g;
+
+	override function isSupportedLink(url:String):Bool {
+		return extractVideoId(url).length > 0;
+	}
+
+	public function extractVideoId(url:String):String {
+		if (matchPeertube.match(url)) return matchPeertube.matched(2);
+		if (matchOldPeertube.match(url)) return matchOldPeertube.matched(1);
+		return "";
+	}
+
+	override function getVideoData(data:VideoDataRequest, callback:(data:VideoData) -> Void) {
+		if (!isSupportedLink(data.url)) {
+			getRawVideoData(data, callback);
+			return;
+		}
+		getPeertubeVideoData(data.url, info -> {
+			if (info == null) {
+				callback({duration: 0});
+				return;
+			}
+			getRawVideoData({url: info.url, atEnd: data.atEnd}, data -> {
+				data.url = info.url;
+				data.title = info.title;
+				callback(data);
+			});
+		});
+	}
+
+	function getRawVideoData(data:VideoDataRequest, callback:(data:VideoData) -> Void) {
+		super.getVideoData(data, callback);
+	}
+
+	function getPeertubeVideoData(url:String, callback:(info:Null<{url:String, title:String}>) -> Void) {
+		final id = extractVideoId(url);
+
+		url = url.replace("pt:", "");
+		if (!url.startsWith("http")) url = 'https://$url';
+		final urlObj = try {
+			new URL(url);
+		} catch (e) {
+			trace(e);
+			callback(null);
+			return;
+		}
+		final host = urlObj.host;
+
+		final isPlaylistItem = url.contains("/p/");
+		if (isPlaylistItem) {
+			final apiUrl = 'https://$host/api/v1/video-playlists/$id/videos';
+			final http = new Http(apiUrl);
+			http.onData = data -> {
+				final json:{data:Array<Dynamic>, total:Int} = Json.parse(data);
+				final arr = json.data;
+				final pos = Std.parseInt(urlObj.searchParams.get("playlistPosition") ?? "1");
+				final item:Dynamic = arr.find(item -> item.position == pos) ?? arr[0];
+				final uuid:String = item.video?.uuid ?? {
+					trace(item);
+					callback(null);
+					return;
+				};
+				getPeertubeVideoData('pt:https://$host/videos/watch/$uuid', callback);
+			}
+			http.onError = err -> {
+				trace(err);
+				callback(null);
+			}
+			http.request();
+			return;
+		}
+
+		final apiUrl = 'https://$host/api/v1/videos/$id';
+		final http = new Http(apiUrl);
+		http.onData = data -> {
+			try {
+				final json = Json.parse(data);
+				final title = json.name ?? "PeerTube video";
+				final playlistUrl = getBestHlsPlaylistUrl(json);
+				if (playlistUrl != null) {
+					callback({
+						url: playlistUrl,
+						title: title
+					});
+					return;
+				}
+
+				final mp4Url = getBestMp4Url(json);
+				if (mp4Url != null) {
+					callback({
+						url: mp4Url,
+						title: title
+					});
+					return;
+				}
+
+				callback(null);
+			} catch (e) {
+				trace(e);
+				callback(null);
+			}
+		}
+
+		http.onError = err -> {
+			trace(err);
+			callback(null);
+		}
+
+		http.request();
+	}
+
+	function getBestHlsPlaylistUrl(json:Dynamic):Null<String> {
+		final playlists:Array<Dynamic> = json.streamingPlaylists;
+		if (playlists == null || playlists.length == 0) return null;
+		return playlists[0].playlistUrl;
+	}
+
+	function getBestMp4Url(json:Dynamic):Null<String> {
+		final files:Array<Dynamic> = json.files;
+		if (files == null || files.length == 0) return null;
+		files.sort(function(a, b) {
+			return b.resolution.id - a.resolution.id;
+		});
+		return files[0].fileDownloadUrl;
+	}
+}
-- 
cgit v1.2.3